Battleye kicking player after completing Hackers Mission

Battleye kicking player after completing Hackers Mission

« posted: Dec 07, 2017, 10:26 PM »
Looking for help with this issue.

On completion of the Hackers Mission on our Arma 3 Wasteland server Battleye kicks the player with the following reason

setvariable restriction #2

I am new to setting servers up and coding so if anyone has encountered this problem and knows a fix for it, it would be much appreciated.

Thanks in advance.
  • Offline AgentRev
  • Developer
  • Veteran
  • ******
  • Posts: 2488

Re: Battleye kicking player after completing Hackers Mission

« Reply #1 posted: Dec 08, 2017, 03:58 AM »
The hacklaptop mission no longer works as a result of restricting bank money stuff server-only to prevent no-life hackers from fucking everything up like the worthless pieces of shit they are.
  • Offline Matt76
  • Mercenary
  • *****
  • Posts: 418
  • co founder of customcombatgaming.com

Re: Battleye kicking player after completing Hackers Mission

« Reply #2 posted: Dec 08, 2017, 08:22 AM »
A few of us have converted this mission to cmoney instead, Ill dig it out when I'm next home

Re: Battleye kicking player after completing Hackers Mission

« Reply #3 posted: Dec 10, 2017, 01:10 AM »
thanks
  • Offline Matt76
  • Mercenary
  • *****
  • Posts: 418
  • co founder of customcombatgaming.com

Re: Battleye kicking player after completing Hackers Mission

« Reply #4 posted: Dec 10, 2017, 11:04 AM »
downloadData.sqf

Code: [Select]
/*
=======================================================================================================================
downloadData - script to download data from a laptop and because of this complete a task (as example)
File: downloadData.sqf
Author: T-800a

=======================================================================================================================
*/

#define T8_varFileSize (["A3W_hackedMissionDlSize", 125072] call getPublicVar)
#define HACKED_ACCOUNT_PERCENTAGE (["A3W_hackedMissionPercentage", 0.25] call getPublicVar)
#define HACKED_EXTRA_FIXMONEY (["A3W_hackedMissionExtraFixMoney", 50000] call getPublicVar)

T8_varTLine01 = "Download cancelled!"; // download aborted
T8_varTLine02 = "Download already in progress by someone else!"; // download already in progress by someone else
T8_varTLine03 = "Download started!"; // download started
T8_varTLine04 = "Download finished! $50,000 added to your inventory!"; // download finished
T8_varTLine05 = "##  Hack Players Cash  ##"; // line for the addaction

T8_varDiagAbort = false;
T8_varDownSucce = false;

downloadActionId = nil;


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

if (isDedicated) exitWith {};

"AddLaptopHandler" addPublicVariableEventHandler {
private [  "_cDT" ];
_laptop = _this select 1;
_cDT = _laptop getVariable [ "Done", false ];
if ( _cDT ) exitWith {};
if(isNil "downloadActionId") then {
downloadActionId = _laptop addAction [ T8_varTLine05, { call T8_fnc_ActionLaptop; }, [], 10, true, false ];
};
};

T8_fnc_abortActionLaptop =
{
if ( T8_varDownSucce ) then
{
// hint "DEBUG - DONE";
T8_varDiagAbort = false;
T8_varDownSucce = false;

} else {
player sideChat T8_varTLine01;
T8_varDiagAbort = true;
T8_varDownSucce = false;
};
};

"RemoveLaptopHandler" addPublicVariableEventHandler
{
_laptop = _this select 1;
_laptop removeAction downloadActionId;
downloadActionId = nil;
};


T8_fnc_ActionLaptop =
{
private [ "_laptop", "_caller", "_id", "_cIU","_totalMoney","_hackedPercent","_playerSide"];
_laptop = _this select 0;
_caller = _this select 1;
_id = _this select 2;

["Initializing...", 5] call mf_notify_client;
sleep random 5;

_cIU = _laptop getVariable [ "InUse", false ];
if ( _cIU ) exitWith { player sideChat T8_varTLine02; };

player sideChat T8_varTLine03;

T8_varDiagAbort = false;

_laptop setVariable [ "InUse", true, true ];

[ _laptop, _id] spawn
{
private [ "_laptop", "_id", "_newFile", "_dlRate" ];

_laptop = _this select 0;
_id = _this select 1;

_newFile = 0;

createDialog "T8_DataDownloadDialog";

sleep 0.5;
ctrlSetText [ 8001, "Connecting ..." ];
sleep 0.5;
ctrlSetText [ 8001, "Connection Speed:" ];
ctrlSetText [ 8003, format [ "%1 kb", T8_varFileSize ] ];
ctrlSetText [ 8004, format [ "%1 kb", _newFile ] ];


//aj - private abort variable due to server load.
private "_abort";
_abort = false;

while { !T8_varDiagAbort && !_abort && alive player && !(player call A3W_fnc_isUnconscious)} do
{
_dlRate = 1000 + random 400;
_newFile = _newFile + _dlRate;

if ( _newFile > T8_varFileSize ) then
{
_dlRate = 0;
_newFile = T8_varFileSize;
ctrlSetText [ 8001, "Download finished!" ];
T8_varDiagAbort = true;
T8_varDownSucce = true;
_abort = true;

_laptop setVariable [ "Done", true, true ];

_totalMoney = 0;
_playerSide = side player;
switch (_playerSide) do
{
case BLUFOR:
{
{   
if (isPlayer _x) then {
if  (side _x == BLUFOR) then {}
else {
_cmoney = _x getVariable ["cmoney",0];
if ( _cmoney > 0 ) then { //might as well check for zero's
_hackedPercent = round(HACKED_ACCOUNT_PERCENTAGE*_cmoney);
_x setVariable [ "cmoney", (_cmoney - _hackedPercent), true ];
_totalMoney = _totalMoney + _hackedPercent;
}
}
}
} forEach playableUnits;
};

case OPFOR:
{
{   
if (isPlayer _x) then {
if  (side _x == OPFOR) then {}
else {
_cmoney = _x getVariable ["cmoney",0];
if ( _cmoney > 0 ) then { //might as well check for zero's
_hackedPercent = round(HACKED_ACCOUNT_PERCENTAGE*_cmoney);
_x setVariable [ "cmoney", (_cmoney - _hackedPercent), true ];
_totalMoney = _totalMoney + _hackedPercent;
}
}
}
} forEach playableUnits;
};

default
{
{   
if (isPlayer _x) then {
//check here for group of player to only reduce money of people outside the group
if  (group _x == group player) then {}
else {
_cmoney = _x getVariable ["cmoney",0];
if ( _cmoney > 0 ) then { //might as well check for zero's
_hackedPercent = round(HACKED_ACCOUNT_PERCENTAGE*_cmoney);
_x setVariable [ "cmoney", (_cmoney - _hackedPercent), true ];
_totalMoney = _totalMoney + _hackedPercent;
}
}
}
} forEach playableUnits;

};
};

_totalMoney = _totalMoney + HACKED_EXTRA_FIXMONEY;
player setVariable ["cmoney", (player getVariable ["cmoney", 0]) + _totalMoney, true];
systemChat format["You have hacked the server and stole players cash to the value of $%1",_totalMoney];

CCGLogger = ["info", format["Hack the server mission has been completed by [%1 (%2) total prize money %3]", name player, getPlayerUID player, _totalMoney]];
        publicVariableServer "CCGLogger";

sleep 5;
};
ctrlSetText [ 8002, format [ "%1 kb/s", _dlRate ] ];
ctrlSetText [ 8004, format [ "%1 kb", _newFile ] ];

sleep 1;
};

T8_varDiagAbort = false;

closeDialog 0;

_laptop setVariable [ "InUse", false, true];
};
};

downloadDataDONE = true;




Re: Battleye kicking player after completing Hackers Mission

« Reply #5 posted: Dec 30, 2017, 05:37 PM »
thanks for the info and code guys, much appreciated